Re: Fit läuft nicht

[Patrick Scheibe <patrick@XXXXXXX.de>]

Moin,

> MMA 7 ist schon merkwürdig.

Naja... eigentlich sollte man wissen, dass das Integral ueber eine
Verteilungsdichte 1 sein muss, wenn man denn schon eine Normalverteilung
auf die Daten pressen will. Nimmt man diesen Umstand und passt den Code
entsprechend an, geht das dann auch ohne Murren:

data = {{500, 130}, {1500, 258}, {2500, 742}, {3500, 1105}, {4500, 
    1705}, {5500, 2680}, {6500, 5556}, {7500, 8391}, {8500, 
    9584}, {9500, 7953}, {10500, 4110}, {11500, 1306}, {12500, 
    92}, {13500, 0}};
sy = Plus @@ Last[Transpose[data]];
{maxx, maxy} = Max @@@ Transpose[data];
data2 = #/{maxx, sy/Length[data]} & /@ data;
GraphicsRow[ListPlot[#, Joined -> True] & /@ {data, data2}]
model = PDF[NormalDistribution[\[Mu], \[Sigma]], x];
sol = NonlinearModelFit[data2, model, {\[Mu], \[Sigma]}, x];
GraphicsRow[{
  Plot[sol[x], {x, 0, 1}, PlotRange -> All, Epilog :> Point[data2]],
  Plot[sy*sol[x/maxx]/Length[data], {x, 0, maxx}, PlotRange -> All, 
   Epilog :> Point[data]]
  }]

Cheers
Patrick

> Kann mir bitte jemand sagen, warum der Fit nicht läuft?
> Danke & guten Rutsch wünscht
> Peter