Re: [Dmug] IsotopeData["Pu241", "HalfLife"]

[Udo und Susanne Krause via demug <demug@XXXXXXX.ch>]

Hallo Peter,

es ist nicht clever ein 120 * 300 = 360'000 Element-Array mit ca. 356'000  
Nullen bei ArrayPlot[] abzugeben, deshalb der Vollständigkeit halber noch  
diese Variante

Clear[isotopenPlot]
isotopenPlot[] := With[{zMax = 120, aMax = 300},
  ArrayPlot[
   SparseArray[
    Reap[Table[
       If[Head[Quiet[
           Check[IsotopeData[{o, oo}, "StandardName"],
            0, {IsotopeData::notent}]]] === String,
        Sow[Rule[{o, oo}, 1]]], {o, zMax}, {oo, aMax}]][[2, 1]]],
   ColorRules -> {1 -> Cyan, 0 -> Yellow}, Mesh -> {zMax, aMax}/5,
   Frame -> True, FrameTicks -> Automatic, FrameLabel -> {"Z", "A"},
   PlotLabel -> "Wolfram::Isotope"]
  ]

die auch nicht ideal ist, denn Reap[...][[2,1]] bedeutet, dass man  
Reap[...][[1]] umsonst ermittelte.

Dann habe ich festgestellt, dass die Hilfe der eigenen Courage nicht  
vertraut, denn mit den Funktionen

Clear[peterSchoen1, peterSchoen2]
peterSchoen1[s_Entity] :=
 Rule[s, Row[{IsotopeData[s, "FullSymbol"]}, Background -> LightBlue,
   Frame -> True, RoundingRadius -> 2]]
peterSchoen2[s_Entity] :=
 Rule[s, Column[{IsotopeData[s, "Symbol"],
    IsotopeData[s, "HalfLife"]}, Background -> LightBlue,
   Frame -> All]]

kann man schlicht via

RelationGraph[DaughterNuclidesQ, vertsPu241,
 Sequence[VertexLabels -> (peterSchoen1 /@ vertsPu241),
  PlotRangePadding -> 0.85, ImageSize -> 500,
  PlotTheme -> "Scientific"]]


das Bildchen klamser-pu241-full-symbol und via

RelationGraph[AlphaDecayQ, vertsPu241,
 Sequence[VertexLabels -> (peterSchoen2 /@ vertsPu241),
  PlotRangePadding -> 0.95, ImageSize -> 900, PlotTheme -> "Business",
   GraphLayout -> "SpectralEmbedding"]]

das Bildchen klamser-pu241-alpha-business erzeugen; letzteres enthält die  
Alphazerfälle unter den Zerfällen, die dieses Plutonium 241 auslöst.

Schönen Sonntag!
Udo.


On Sat, 14 Sep 2019 10:46:20 +0200, Udo und Susanne Krause  
<su.krause@XXXXXXX.ch> wrote:

> Hallo Peter,
>
> das folgt der üblichen Mathematicaprogrammierung, machen wir zunächst  
> einen Arrayplot der bei Wolfram bekannten Isotope
>
> In[45]:= Clear[isotopenPlot]
> isotopenPlot[] := With[{zMax = 120, aMax = 300},
>    ArrayPlot[
>     Table[If[
>       Head[Quiet[
>          Check[IsotopeData[{o, oo}, "StandardName"],
>           0, {IsotopeData::notent}]]] === String,
>       1, (* else *)
>       0 ], {o, zMax}, {oo, aMax}],
>     ColorRules -> {1 -> Cyan, 0 -> Yellow}, Mesh -> {zMax, aMax}/5,
>     Frame -> True, FrameTicks -> Automatic, FrameLabel -> {"Z", "A"},
>     PlotLabel -> "Wolfram::Isotope"]
>    ]
>
> auf einschlägigen Seiten findet man, dass Kernladungszahlen > 120 und  
> Massenzahlen > 300 nicht gemischelt werden konnten, demnach nicht  
> existieren. Das gibt das Bild im Anhang.
>
> Jetzt müssten Sie wg.
>
> X^{A}_{Z} -> Y^{A-4}_{Z-2} + He^{4}_{2} + dE
>
> was der Alphazerfall in LaTeX-Notation ist, die Kette herunterlaufen,  
> mit DaughterNuclides kontrollieren, dass Y ein daughter nuclide von X  
> ist, die Halbwertszeit abholen und dieses rekursiv ausführen, bis kein  
> Zweig mehr Töchter meldet. Am Schluss einen schönen Graphen fertigen.
>
> Go ahead!
>
> Grüsse
> Udo.
>
>
> On Sun, 08 Sep 2019 20:30:31 +0200, Peter Klamser via demug  
> <demug@XXXXXXX.ch> wrote:
>
> > Hallo,
> > Ich würde gerne mit MMA12 über IsotopeData["Pu241", "HalfLife"] eine  
> > Liste
> > der Zerfallsprodukte in der Zerfallskette mit der jeweiligen  
> > Halbwertszeit
> > nur für Alphazerfälle erstellen.
> >
> > Die Beispiele bei wri.com sind sehr komplex.
> >
> > Weiß jemand wie das geht?
> >
> > Danke sagt Peter
> > _______________________________________________
> > DMUG Deutschsprachiges Mathematica-Forum demug@XXXXXXX.ch
> > http://www.mathematica.ch/mailman/listinfo/demug
> > Archiv: http://www.mathematica.ch/archiv.html

klamser-pu241-full-symbol.jpg
Description: JPEG image

klamser-pu241-alpha-business.jpg
Description: JPEG image

_______________________________________________
DMUG Deutschsprachiges Mathematica-Forum demug@XXXXXXX.ch
http://www.mathematica.ch/mailman/listinfo/demug
Archiv: http://www.mathematica.ch/archiv.html