Re[3]: Aufgabe::homothetische gewöhnliche Dgl.

["Udo und Susanne Krause" <su.krause@XXXXXXX.ch>]

Hallo Peter,

> Na so was... In dem Manipulationsobjekt ...

Na so was, Sie haben die Koeffizienten direkt ausgerechnet! Das ist gar  
nicht so einfach. Hier ist ein einfacher Weg, der zum selben Ergebnis  
führt: Sei p eine Funktion, welche Lösung der gegebenen Dgl. ist, dann  
muss p mit der Dgl. auch die folgenden Beziehungen erfüllen:

(* the rules of the game *)
Clear[p];
p /: D[p[x_], {x_, 1}] := p[k x] (* by definition *)
p /: D[p[x_], {x_, n_?IntegerQ /; n > 1}] := D[p[k x], {x, n - 1}]
p /: D[p[x_], x_] := D[p[x], {x, 1}]
p /: D[p[x_], {x_}] := D[p[x], {x, 1}]
p /: D[p[k^(m_: 1) x_], {x_, 1}] := k^m p[k^(m + 1) x]
p /: D[p[k^(m_: 1) x_], {x_, n_?IntegerQ /; n > 1}] :=
 k^m D[p[k^(m + 1) x], {x, n - 1}]
p /: D[p[k^(m_: 1) x_], x_] := D[p[k^m x], {x, 1}]
p /: D[p[k^(m_: 1) x_], {x_}] := D[p[k^m x], {x, 1}]

Interessant ist nur die fünfte Regel, die man direkt nachrechnen kann und  
muss. Daraus folgt beispielsweise

In[23]:= D[p[x], {x, 9}]
Out[23]= k^36 p[k^9 x]

oder allgemein

D[p[x], {x, n}] = k^(n (n - 1)/2) p[k^n x]

Diese Beziehung kann man für einen Koeffizientenvergleich nutzen

In[7]:= Clear[cof];
cof = With[{l = 20, ld = 10},
   Table[
    Collect[
     D[Sum[Subscript[a, i] x^i, {i, 1, l}], {x, n}] -
      k^(n (n - 1)/2) Sum[Subscript[a, i] (k^n x)^i, {i, 1, l}],
     x], {n, 1, ld}]
   ];

Es folgt insbesondere, dass alle Koeffizienten a_i von a_1 und einer  
Funktion von k allein bestimmt sind:

In[9]:= Coefficient[cof, x, 1]

Out[9]= {-k Subscript[a, 1] +
  2 Subscript[a, 2], -k^3 Subscript[a, 1] +
  6 Subscript[a, 3], -k^6 Subscript[a, 1] +
  24 Subscript[a, 4], -k^10 Subscript[a, 1] +
  120 Subscript[a, 5], -k^15 Subscript[a, 1] +
  720 Subscript[a, 6], -k^21 Subscript[a, 1] +
  5040 Subscript[a, 7], -k^28 Subscript[a, 1] +
  40320 Subscript[a, 8], -k^36 Subscript[a, 1] +
  362880 Subscript[a, 9], -k^45 Subscript[a, 1] +
  3628800 Subscript[a, 10], -k^55 Subscript[a, 1] +
  39916800 Subscript[a, 11]}

man vermutet daher

a_i = k^(i (i - 1)/2) a_1/i!

weil die Ausdrücke alle einzeln Null sein müssen, wenn die Dgl. erfüllt  
sein soll. Es könnten nun noch Widersprüche auftreten bei der Betrachtung  
von

Coefficient[cof, x, 2], Coefficient[cof, x, 3], ...,

die Beziehungen zwischen a_2 und a_n (n > 2), zw. a_3 und a_n (n > 3), ...  
herstellen. Das ist aber nicht der Fall, wie man sich durch Einsetzen  
überzeugt. Also ist die Lösung

Remove[f, g];
f[x_, n_?IntegerQ /;
   n > 0] := \[Alpha] Sum[k^(m (m - 1)/2) x^m/m!, {m, 0, n}] /;
  x =!= k
g[x_?NumericQ, k_?NumericQ /; k != 0 && k !=  -1] :=
 NSum[k^(m (m - 1)/2) x^m/m!, {m, 0, Infinity}]
g[x_, 0] := x + 1 (* Subscript[a, 1] is the only coefficient *)
g[x_, -1] := Sin[x] + Cos[x] (* performance *)

für die numerische Definition g wurde \[Alpha] = 1 gesetzt. Es ist
g[x_, 1] = Exp[x] und für |k| > 1 ist die Reihe divergent.

Mit den besten Grüssen
Udo.

--
Using Opera's revolutionary e-mail client: http://www.opera.com/mail/